Imports System.Data.SqlTypes
Imports System.Data.SqlClient
'''<summary>Person</summary>
'''<seealso
'''cref="T:Vertragsverwaltung.TKB.VV.Utils.MySecurity">TKB.VV.Utils.MySecurity</seealso>
'''<seealso
'''cref="T:Vertragsverwaltung.TKB.VV.Utils.MyMessage">TKB.VV.Utils.MyMessage</seealso>
'''<seealso cref="N:Vertragsverwaltung.TKB.VV.Utils">TKB.VV.Utils</seealso>
''' 
Public Class frmKuendigungsfrist

#Region "Deklarationen"
    Dim Kuendigungsfrist As New TKB.VV.Vertrag.clsKuendigungsfrist

    Dim sec As New TKB.VV.Utils.MySecurity
    Dim msg As New TKB.VV.Utils.MyMessage
    Dim FormReadonly As Boolean = False

    Dim FormDataChanged As Boolean = False

    Dim Kuendigungsfristnr As Integer

    Dim m_vertragselementnr As Integer
    Dim Neuer_Datensatz As Boolean = False

    Property Vertragselementnr() As Integer
        Get
            Return m_vertragselementnr
        End Get
        Set(ByVal value As Integer)
            m_vertragselementnr = value
        End Set
    End Property
#End Region

#Region "Eventhandler ChangeEreignisse"
    ''' <summary>
    ''' Allg Eventhandler für Chanage-Ereignise festlegen
    ''' </summary>
    ''' <param name="Container"></param>
    ''' <remarks></remarks>
    Private Sub AddChanges(ByVal Container As Control)
        Dim l As New List(Of Control)
        Me.GetControl(Me, "*", l)
        Dim evh As EventHandler = AddressOf ChangesMade
        For Each c As Control In l
            If TypeOf c Is TextBox Then
                Dim ctl As TextBox = c
                AddHandler ctl.TextChanged, evh
            End If
            If TypeOf c Is MaskedTextBox Then
                Dim ctl As MaskedTextBox = c
                AddHandler ctl.TextChanged, evh
            End If
            If TypeOf c Is ComboBox Then
                Dim ctl As ComboBox = c
                AddHandler ctl.SelectedValueChanged, evh
            End If
            If TypeOf c Is CheckBox Then
                Dim ctl As CheckBox = c
                AddHandler ctl.CheckedChanged, evh
            End If
        Next
    End Sub
    ''' <summary>
    ''' Envent-Handler für Change-Ereignisse
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub ChangesMade(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.FormDataChanged = True
    End Sub

    ''' <summary>
    ''' Sucht in den Base-Controls sämtliche Controls mit dem Namen in "Key" (Wildcards * möglich) und listet
    ''' die gefundnen Controls in der Liste L zur weiteren Bearbeitung
    ''' </summary>
    ''' <param name="BaseControl">Base-Contrlo (z.B. aktuelles Formular</param>
    ''' <param name="Key">Schlüssel welcher gesucht werden soll</param>
    ''' <param name="L">Liste der gefundenen Objekte</param>
    ''' <returns>True wenn eines oder mehr Controls gefunden wurden, false wenn kein Control gefunden wurde.
    ''' </returns>
    ''' <remarks></remarks>
    Private Function GetControl(ByVal BaseControl As Control, ByVal Key As String, ByRef L As List(Of Control), Optional ByVal ReturnAtFirstElement As Boolean = False) As Boolean
        If L Is Nothing Then L = New List(Of Control)
        Dim Gut As Boolean
        Dim ReturnFlag As Boolean = False
        If Key IsNot Nothing Then Key = Key.ToLower

        If BaseControl.HasChildren = True Then
            For Each ctl As Control In BaseControl.Controls
                Gut = False
                If Key Is Nothing Then
                    Gut = True
                Else
                    If ctl.Name.Length >= Key.Length Then
                        Key = Key.ToLower
                        If Key.StartsWith("*") Then
                            If Key.Substring(1) = ctl.Name.ToLower.Substring(ctl.Name.Length - (Key.Length - 1), Key.Length - 1) Then Gut = True
                        ElseIf Key.EndsWith("*") Then
                            If Key.Substring(0, Key.Length - 1) = ctl.Name.ToLower.Substring(0, Key.Length - 1) Then Gut = True
                        Else
                            If Key = ctl.Name.ToLower Then Gut = True
                        End If
                    End If
                End If

                If Gut = True Then
                    L.Add(ctl)
                    If ReturnAtFirstElement = True Then ReturnFlag = True
                End If
                If ReturnFlag = False Then
                    Call GetControl(ctl, Key, L)
                End If
            Next
        End If

        If L.Count - 1 > -1 Then
            Return True
        Else
            Return False
        End If
    End Function

#End Region

#Region "Closing / Check_Changes"

    ''' <summary>
    ''' Schliessen des Formulars
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub FormularClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        If Me.FormReadonly = True Then Exit Sub
        If check_changes() = False Then
            e.Cancel = True
        Else
            If Me.Kuendigungsfrist.Neuer_Datensatz = True Then Me.Kuendigungsfrist.Delete(Me.Kuendigungsfrist.iKuendigungsfristNr.Value)
            Globals.MyEventHanlder.Kuendigungsfrist_Closed()
            Me.Dispose()
        End If
    End Sub

    ''' <summary>
    ''' Prüfung, ob Datenänderungen vorgenommen wurden. 
    ''' </summary>
    ''' <remarks></remarks>
    Private Function Check_Changes() As Boolean
        If Me.FormReadonly Then Exit Function
        Dim msgres As MsgBoxResult
        If Me.FormDataChanged Then
            msgres = msg.Show_MessageYesNoCancel(3)
            Select Case msgres
                Case MsgBoxResult.Yes
                    Save_data()
                    Return True
                Case MsgBoxResult.Cancel
                    Return False
                Case MsgBoxResult.No
                    Return True
            End Select
        Else
            Return True
        End If
    End Function

#End Region

#Region "Formular"
    ''' <summary>
    ''' Destructor Dispose
    ''' </summary>
    ''' <remarks></remarks>
    Overloads Sub Dispose()
        Me.Kuendigungsfrist.Dispose()
        sec = Nothing
        msg = Nothing
        MyBase.Dispose()
    End Sub

    ''' <summary>
    ''' Formular-Initialisierung
    ''' </summary>
    ''' <param name="Nr">PersonenNr</param>
    ''' <param name="Vertragspartnernr">VertragspartnerNr</param>
    ''' <remarks></remarks>
    Public Sub New(ByVal Nr As Integer, ByVal Vertragselementnr As Integer, Optional ByVal iReadOnly As Boolean = False, Optional ByVal CreateNew As Boolean = False)
        MyBase.New()
        Me.InitializeComponent()
        If CreateNew = True Then
            Me.Kuendigungsfristnr = Me.Kuendigungsfrist.Add_New(Vertragselementnr)
            Me.Neuer_Datensatz = True
        Else
            Kuendigungsfristnr = Nr
        End If
        Me.Vertragselementnr = Vertragselementnr
        Me.FormReadonly = iReadOnly
    End Sub
    ''' <summary>
    ''' Laden des Formulars
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub frmKuendigungsfrist_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        sec.Set_Form_Security(Me)

        If Me.FormReadonly = True Then Me.TSBtnSave.Enabled = False

        If Me.TSBtnSave.Enabled = False Or Me.TSBtnSave.Visible = False Then
            Me.FormReadonly = True
            Me.TSBtnCopy.Enabled = False
            Me.TSBtnNew.Enabled = False
            Me.TSBtnDelete.Enabled = False
        Else
            Me.FormReadonly = False
        End If

        Load_Securitylevel()
        Get_Data(Kuendigungsfristnr)
        If Me.Neuer_Datensatz Then Me.Kuendigungsfrist.Neuer_Datensatz = True
        Me.AddChanges(Me)
        If Me.FormReadonly Then sec.Set_Form_Readonly(Me)
    End Sub

    ''' <summary>
    ''' Handelt das Change-Ereignis eines Datetimepckers und stellt das ausgewählte Datum in das entsprechende Textfeld
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub DateTimePicker_ValueChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles dtPickerKuendigungstermin.ValueChanged
        Dim s As String
        Dim obj As DateTimePicker = sender
        s = obj.Name
        s = "txt" + s.Substring(8, s.Length - 8)
        Dim l As New List(Of Control)
        Dim txtb As MaskedTextBox
        GetControl(Me, s, l)
        For Each ctl As Control In l
            txtb = CType(ctl, MaskedTextBox)
            txtb.Text = obj.Value
        Next
    End Sub
#End Region


#Region "Buttons"
    ''' <summary>
    ''' Save-Button geklickt
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnSave_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnSave.Click
        Me.Save_Data()
    End Sub
    ''' <summary>
    ''' Schliessen-Button betätigt
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnQuit_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnQuit.Click
        Me.Close()
    End Sub
    ''' <summary>
    ''' kopieren
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnCopy_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnCopy.Click
        Try
            Check_Changes()
            Me.Get_Data(Kuendigungsfrist.Create_Copy(Me.Kuendigungsfrist.iKuendigungsfristNr.Value))
        Catch
        End Try
    End Sub
    ''' <summary>
    ''' Neu
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnNew_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnNew.Click
        Try
            Me.Get_Data(Me.Kuendigungsfrist.Add_New(Me.Vertragselementnr))
            Me.Kuendigungsfrist.Neuer_Datensatz = True
        Catch
        End Try
    End Sub
    ''' <summary>
    ''' löschen
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnDelete_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnDelete.Click
        If msg.Show_MessageYesNo(260) = MsgBoxResult.Yes Then
            Me.Kuendigungsfrist.Delete_Kuendigungsfrist(Me.Kuendigungsfrist.iKuendigungsfristNr.Value)
            Me.Close()
        End If
    End Sub

#End Region

#Region "Security"

    ''' <summary>
    ''' Laden der Securitylevel-Daten in die Combobox
    ''' </summary>
    ''' <remarks></remarks>
    Private Sub Load_Securitylevel()
        Dim seclevel As New TKB.VV.DB.clsSecurityLevel
        Dim secleveldata As New DataTable

        seclevel.cpMainConnectionProvider = Globals.conn
        Globals.conn.OpenConnection()
        secleveldata = seclevel.SelectAll
        Globals.conn.CloseConnection(True)

        Me.cboxSecurityLevel.DataSource = secleveldata
        Me.cboxSecurityLevel.DisplayMember = "Bezeichnung"
        Me.cboxSecurityLevel.ValueMember = "SecurityLevelNr"

        seclevel.Dispose()

    End Sub

#End Region

#Region "Daten"
    ''' <summary>
    ''' Person laden und präsentieren
    ''' </summary>
    ''' <param name="Nr"></param>
    ''' <remarks></remarks>
    Private Sub Get_Data(ByVal Nr As Integer)
        Me.Kuendigungsfrist.Get_Kuendigungsfrist(Nr)
        Me.txtZeitspanne.Text = Me.Kuendigungsfrist.sVarZeitspanne.ToString
        Me.txtKuendigungsfrist.Text = Me.Kuendigungsfrist.sKuendigungsfirst.ToString
        Me.txtKuendigungstermin.Text = Me.Kuendigungsfrist.daKuendigungstermin.ToString
        Me.txtBemerkung.Text = Me.Kuendigungsfrist.sBemerkung.Value
        Me.txtErstellt_am.Text = Me.Kuendigungsfrist.daErstellt_am.ToString
        Me.txtMutiert_am.Text = Me.Kuendigungsfrist.daMutiert_am.ToString
        Me.txtMutierer.Text = Me.Kuendigungsfrist.iMutierer.Value
        Me.cbAktiv.Checked = Me.Kuendigungsfrist.bAktiv.Value = True
        Me.cboxSecurityLevel.SelectedValue = Me.Kuendigungsfrist.iSecurityLevelNr.Value
        Me.FormDataChanged = False

    End Sub
    ''' <summary>
    ''' Daten sichern, sofern Änderungen vorgenommen worden sind
    ''' </summary>
    ''' <remarks></remarks>
    Private Sub Save_Data()

        If Me.FormDataChanged Then
            Me.Kuendigungsfrist.sVarZeitspanne = New SqlString(CType(Me.txtZeitspanne.Text, String))
            Me.Kuendigungsfrist.sKuendigungsfirst = New SqlString(CType(Me.txtKuendigungsfrist.Text, String))
            If IsDate(Me.txtKuendigungstermin.Text) Then Me.Kuendigungsfrist.daKuendigungstermin = New SqlDateTime(CType(Me.txtKuendigungstermin.Text, DateTime))
            Me.Kuendigungsfrist.sBemerkung = New SqlString(CType(Me.txtBemerkung.Text, String))
            Me.Kuendigungsfrist.bAktiv = New SqlBoolean(CType(Me.cbAktiv.Checked, Boolean))
            Me.Kuendigungsfrist.iSecurityLevelNr = New SqlInt32(CType(Me.cboxSecurityLevel.SelectedValue, Int32))
            Get_Data(Me.Kuendigungsfrist.Save_Data)
            Me.FormDataChanged = False
        End If
    End Sub

#End Region


End Class