ITSM/Vertragsverwaltung - Kopie/Applikation/Applikationabhaengigkeit/frmApplikationAbhaengigkeit.vb

Imports System
Imports System.Data
Imports System.Data.SqlTypes
Imports System.Data.SqlClient
Public Class frmApplikationAbhaengigkeit
#Region "Deklarationen"

    Dim Applikationabhaengigkeitdata As New TKB.VV.Applikation.clsApplikationsabhaengigkeit
    Dim sec As New TKB.VV.Utils.MySecurity
    Dim msg As New TKB.VV.Utils.MyMessage
    Dim FormReadonly As Boolean = False
    Dim FormDataChanged As Boolean = False
    Dim SpaltenTitel As New TKB.VV.Utils.Tabellenspalte

    Private Akutelle_Referenz As Integer = 0
    Private Aktuelle_Applikation1 As Integer
    Private Aktuelle_Applikation2 As Integer

    Private Anzeige As Boolean = False
    Public Neuer_Datensatz As Boolean = False

#End Region


#Region "Closing / Check_Changes"

    ''' <summary>
    ''' Schliessen des Formulars
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub FormularClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        If Me.FormReadonly = True Then Exit Sub
        If Check_Changes() = False Then
            e.Cancel = True
        Else
            If Me.Applikationabhaengigkeitdata.Neuer_Datensatz = True Then Me.Applikationabhaengigkeitdata.Delete(Me.Applikationabhaengigkeitdata.iApplikationAbhaengigkeitNr.Value)
            Globals.MyEventHanlder.Refernzvertrag_Closed()
            Me.dispose()
        End If
    End Sub

    ''' <summary>
    ''' Prüfung, ob Datenänderungen vorgenommen wurden. 
    ''' </summary>
    ''' <remarks></remarks>
    Private Function Check_Changes() As Boolean
        If Me.FormReadonly Then Exit Function
        Dim msgres As MsgBoxResult
        If Me.FormDataChanged Then
            msgres = msg.Show_MessageYesNoCancel(3)
            Select Case msgres
                Case MsgBoxResult.Yes
                    Save_data()
                    Return True
                Case MsgBoxResult.Cancel
                    Return False
                Case MsgBoxResult.No
                    Return True
            End Select
        Else
            Return True
        End If
    End Function

#End Region


#Region "Formular"

    ''' <summary>
    ''' Standard Constructore New
    ''' </summary>
    ''' <remarks></remarks>
    Sub New()
        InitializeComponent()
        Me.Akutelle_Referenz = -1
    End Sub

    ''' <summary>
    ''' Formualr mit Vertragselementnr und Anzeigestatus öffnen
    ''' </summary>
    ''' <param name="Vertragselementnr">Nr des Vertragspartners</param>
    ''' <param name="Anzeige">True=Readonly, False=normal</param>
    ''' <remarks></remarks>
    Sub New(ByVal Referenznr As Integer, ByVal Vertragselementnr As Integer, ByVal Anzeige As Boolean, Optional ByVal CreateNew As Boolean = False)
        MyBase.New()
        InitializeComponent()
        If CreateNew Then
            Me.Akutelle_Referenz = Me.Applikationabhaengigkeitdata.Add_New(Vertragselementnr)
            Me.Neuer_Datensatz = True
        Else
            Me.Akutelle_Referenz = Referenznr
        End If
        Me.Anzeige = Anzeige
    End Sub
    Public Overloads Sub dispose()
        Me.Applikationabhaengigkeitdata.dispose()
        sec = Nothing
        msg = Nothing
        MyBase.Dispose()
    End Sub


    Private Sub frmReferenzvertraege_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        If Anzeige = True Then
            Me.TSBtnSave.Enabled = False
        End If
        If Me.TSBtnSave.Enabled = False Or Me.TSBtnSave.Visible = False Then
            Me.FormReadonly = True
            Me.TSBtnNew.Enabled = False
            Me.TSBtnDelete.Enabled = False
        Else
            Me.FormReadonly = False
        End If


        Load_Securitylevel()

        AddChanges(Me)
        Get_Data(Me.Akutelle_Referenz)
        If Me.Neuer_Datensatz = True Then
            Me.Applikationabhaengigkeitdata.Neuer_Datensatz = True
            Me.Neuer_Datensatz = False
        End If
        If Me.FormReadonly Then sec.Set_Form_Readonly(Me)
    End Sub
#End Region


#Region "Buttons/Menu"

    ''' <summary>
    ''' Formular schliessen
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnQuit_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnQuit.Click
        Me.Close()
    End Sub

    ''' <summary>
    ''' Sicherungs-Button betätigt
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnSave_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnSave.Click
        Me.Save_data()
        Me.txtMutiertam.Text = Me.Applikationabhaengigkeitdata.daMutiert_am.ToString
        Me.FormDataChanged = False
    End Sub


    ''' <summary>
    ''' Neuer Datensatz erstellen
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnNew_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnNew.Click
        If Me.Check_Changes = False Then Exit Sub
        Me.Get_Data(Me.Applikationabhaengigkeitdata.Add_New(Me.Aktuelle_Applikation1))
        Me.Applikationabhaengigkeitdata.Neuer_Datensatz = True
    End Sub
    ''' <summary>
    ''' Aktueller Datensatz inaktivieren
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub TSBtnDelete_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles TSBtnDelete.Click
        If msg.Show_MessageYesNo(250) = MsgBoxResult.Yes Then
            Me.Applikationabhaengigkeitdata.Delete_Referenz(Me.Applikationabhaengigkeitdata.iApplikationAbhaengigkeitNr.Value)
            Me.Close()
        End If
    End Sub

    ''' <summary>
    ''' Menu Beenden
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub BeendenToolStripMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles BeendenToolStripMenuItem.Click
        Me.TSBtnQuit_Click(sender, e)
    End Sub


#End Region

#Region "Eventhandler ChangeEreignisse"
    ''' <summary>
    ''' Allg Eventhandler für Chanage-Ereignise festlegen
    ''' </summary>
    ''' <param name="Container"></param>
    ''' <remarks></remarks>
    Private Sub AddChanges(ByVal Container As Control)
        Dim l As New List(Of Control)
        Me.GetControl(Me, "*", l)
        Dim evh As EventHandler = AddressOf ChangesMade
        For Each c As Control In l
            If TypeOf c Is TextBox Then
                Dim ctl As TextBox = c
                AddHandler ctl.TextChanged, evh
            End If
            If TypeOf c Is MaskedTextBox Then
                Dim ctl As MaskedTextBox = c
                AddHandler ctl.TextChanged, evh
            End If
            If TypeOf c Is ComboBox Then
                Dim ctl As ComboBox = c
                AddHandler ctl.SelectedValueChanged, evh
            End If
            If TypeOf c Is CheckBox Then
                Dim ctl As CheckBox = c
                AddHandler ctl.CheckedChanged, evh
            End If
        Next
    End Sub
    ''' <summary>
    ''' Envent-Handler für Change-Ereignisse
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    ''' <remarks></remarks>
    Private Sub ChangesMade(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.FormDataChanged = True
        Dim objtype As System.Type = sender.GetType
        If objtype.Name = "MaskedTextBox" Then
            Dim o As MaskedTextBox = sender
            If o.Text = "01.01.1900" Then o.Text = "  .  .    "
        End If
    End Sub

    ''' <summary>
    ''' Sucht in den Base-Controls sämtliche Controls mit dem Namen in "Key" (Wildcards * möglich) und listet
    ''' die gefundnen Controls in der Liste L zur weiteren Bearbeitung
    ''' </summary>
    ''' <param name="BaseControl">Base-Contrlo (z.B. aktuelles Formular</param>
    ''' <param name="Key">Schlüssel welcher gesucht werden soll</param>
    ''' <param name="L">Liste der gefundenen Objekte</param>
    ''' <returns>True wenn eines oder mehr Controls gefunden wurden, false wenn kein Control gefunden wurde.
    ''' </returns>
    ''' <remarks></remarks>
    Private Function GetControl(ByVal BaseControl As Control, ByVal Key As String, ByRef L As List(Of Control), Optional ByVal ReturnAtFirstElement As Boolean = False) As Boolean
        If L Is Nothing Then L = New List(Of Control)
        Dim Gut As Boolean
        Dim ReturnFlag As Boolean = False
        If Key IsNot Nothing Then Key = Key.ToLower

        If BaseControl.HasChildren = True Then
            For Each ctl As Control In BaseControl.Controls
                Gut = False
                If Key Is Nothing Then
                    Gut = True
                Else
                    If ctl.Name.Length >= Key.Length Then
                        Key = Key.ToLower
                        If Key.StartsWith("*") Then
                            If Key.Substring(1) = ctl.Name.ToLower.Substring(ctl.Name.Length - (Key.Length - 1), Key.Length - 1) Then Gut = True
                        ElseIf Key.EndsWith("*") Then
                            If Key.Substring(0, Key.Length - 1) = ctl.Name.ToLower.Substring(0, Key.Length - 1) Then Gut = True
                        Else
                            If Key = ctl.Name.ToLower Then Gut = True
                        End If
                    End If
                End If

                If Gut = True Then
                    L.Add(ctl)
                    If ReturnAtFirstElement = True Then ReturnFlag = True
                End If
                If ReturnFlag = False Then
                    Call GetControl(ctl, Key, L)
                End If
            Next
        End If

        If L.Count - 1 > -1 Then
            Return True
        Else
            Return False
        End If
    End Function


#End Region

#Region "Daten"
    ''' <summary>
    ''' Daten ab DB laden uns ins Form befüllen
    ''' </summary>
    ''' <param name="Vertragselementnr"></param>
    ''' <remarks></remarks>
    Private Sub Get_Data(ByVal Applikationabhaengigkeitnr As Integer)
        Try
            Me.Applikationabhaengigkeitdata.Get_Applikationabhaengigkeit(Applikationabhaengigkeitnr)
            Me.Aktuelle_Applikation1 = Me.Applikationabhaengigkeitdata.iApplikationnr1.Value
            Me.Aktuelle_Applikation2 = Me.Applikationabhaengigkeitdata.iApplikationnr2.Value

            Me.txtApplikation1.Text = Me.Applikationabhaengigkeitdata.Applname1
            Me.txtApplikation2.Text = Me.Applikationabhaengigkeitdata.Applname2

            Me.txtErstelltam.Text = Me.Applikationabhaengigkeitdata.daErstellt_am.ToString
            Me.txtMutiertam.Text = Applikationabhaengigkeitdata.daMutiert_am.ToString
            Me.txtMutierer.Text = Applikationabhaengigkeitdata.iMutierer.ToString
            Try
                Me.cbaktiv.Checked = Applikationabhaengigkeitdata.bAktiv.Value = True

            Catch ex As Exception
                Me.cbaktiv.Checked = True
            End Try
            Me.cboxSecurityLevel.SelectedValue = Applikationabhaengigkeitdata.iSecurityLevelNr.Value

            Me.txtBemerkung.Text = Applikationabhaengigkeitdata.sBeschreibung.ToString
            If Not Anzeige Then
                For Each ctl As ToolStripButton In Me.ToolStrip1.Items
                    ctl.Enabled = True
                Next
            End If
            sec.Set_Form_Security(Me)
            Me.FormDataChanged = False
        Catch ex As Exception
            For Each ctl As ToolStripButton In Me.ToolStrip1.Items
                ctl.Enabled = False
            Next
            Me.TSBtnQuit.Enabled = True
        End Try
        Me.FormDataChanged = False
    End Sub
    ''' <summary>
    ''' Daten ab Form speichern
    ''' </summary>
    ''' <remarks></remarks>
    Private Sub Save_data()
        Me.Applikationabhaengigkeitdata.iApplikationAbhaengigkeitNr = New SqlInt32(CType(Me.Akutelle_Referenz, Int32))
        Me.Applikationabhaengigkeitdata.iApplikationnr1 = New SqlInt32(CType(Me.Aktuelle_Applikation1, Int32))
        Me.Applikationabhaengigkeitdata.iApplikationnr2 = New SqlInt32(CType(Me.Aktuelle_Applikation2, Int32))

        Me.Applikationabhaengigkeitdata.sBeschreibung = New SqlString(CType(Me.txtBemerkung.Text, String))
        Me.Applikationabhaengigkeitdata.bAktiv = New SqlBoolean(CType(Me.cbaktiv.Checked = True, Boolean))
        Me.Applikationabhaengigkeitdata.Save_Data()
    End Sub
#End Region

#Region "Security"
    ''' <summary>
    ''' Laden der Securitylevel-Daten in die Combobox
    ''' </summary>
    ''' <remarks></remarks>
    Private Sub Load_Securitylevel()
        Dim seclevel As New TKB.VV.DB.clsSecurityLevel
        Dim secleveldata As New DataTable

        seclevel.cpMainConnectionProvider = Globals.conn
        Globals.conn.OpenConnection()
        secleveldata = seclevel.SelectAll
        Globals.conn.CloseConnection(True)

        Me.cboxSecurityLevel.DataSource = secleveldata
        Me.cboxSecurityLevel.DisplayMember = "Bezeichnung"
        Me.cboxSecurityLevel.ValueMember = "SecurityLevelNr"

        seclevel.Dispose()
    End Sub
#End Region


    Private Sub btnApplikationsuche1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnApplikationsuche1.Click
        Try
            Dim f As New frmVertragselementApplikation(Me.Aktuelle_Applikation1, True)
            f.ShowDialog()
            If f.SelectedApplication <> 0 Then
                Me.Applikationabhaengigkeitdata.iApplikationnr1 = New SqlInt32(CType(f.SelectedApplication, Int32))
                Me.txtApplikation1.Text = Me.Applikationabhaengigkeitdata.Applname1
                Me.Aktuelle_Applikation1 = Me.Applikationabhaengigkeitdata.iApplikationnr1.Value

            End If
        Catch ex As Exception
        End Try

    End Sub

    Private Sub btnApplikationSuche2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnApplikationSuche2.Click
        Dim f As New frmVertragselementApplikation(Me.Aktuelle_Applikation1, True)
        f.ShowDialog()
        If f.SelectedApplication <> 0 Then
            Me.Applikationabhaengigkeitdata.iApplikationnr2 = New SqlInt32(CType(f.SelectedApplication, Int32))
            Me.txtApplikation2.Text = Me.Applikationabhaengigkeitdata.Applname2
            Me.Aktuelle_Applikation2 = Me.Applikationabhaengigkeitdata.iApplikationnr2.Value
        End If

    End Sub
End Class