Initial

2024-09-16 10:52:57 +02:00
commit a335fed256
95 changed files with 7409 additions and 0 deletions
@@ -0,0 +1,32 @@
+Imports System.Xml
+
+Namespace LsvBe
+    Public Class CanceledDocuments
+        Inherits DocumentsDetermination
+
+        ''' <summary>
+        ''' Hebt die LSV BEs gemäss Contract auf.
+        ''' Dazu wird der ConnectionString benötigt
+        ''' </summary>
+        ''' <returns>True, wenn ein einziges Dokument identifiziert und aufgehoben werden konnte. Sonst False</returns>
+        Public Overrides Function Render() As Boolean
+            Dim ret As Boolean = False
+
+            Dim existingDocuments As ExistingDocuments = New ExistingDocuments()
+            existingDocuments.ConnectionString = Me.ConnectionString
+            existingDocuments.Contract = Me.Contract
+            existingDocuments.Render()
+            Me.Results.AddRange(existingDocuments.Results)
+
+            If existingDocuments.Items.Count = 1 Then
+                For Each dokument As EdokaDokument In existingDocuments.Items
+                    ret = dokument.Cancel("EDKB04 hat eine LSV Stammdaten Message von Avaloq erhalten und deshalb das Dokument aufgehoben")
+                    If ret Then Me.Items.Add(dokument)
+                Next
+            End If
+
+            Return ret
+        End Function
+    End Class
+
+End Namespace
@@ -0,0 +1,48 @@
+Namespace LsvBe
+    Public Class ExistingDocuments
+        Inherits DocumentsDetermination
+
+        ''' <summary>
+        ''' Füllt Items mit passenden Dokumenten. Zuerst wird nur mit Partner- und Paginatornummer gesucht.
+        ''' Die restlichen Suchkriterien werden erst angewendet, wenn mit Partner- und Paginatornummer
+        ''' keine passenden Dokumente gefunden werden können.
+        ''' </summary>
+        ''' <returns>Always true</returns>
+        Public Overrides Function Render() As Boolean
+            Dim ret As Boolean = True
+            Dim partnerNummer As String = XmlHelper.GetItemValueByTagName(Me.Contract, "partnerNummer")
+            If Not String.IsNullOrEmpty(partnerNummer) Then
+                Dim dokumentList As DokumentList = New DokumentList(Me.Contract, partnerNummer)
+                dokumentList.AddSelektor("pagi_nr", "Paginatornummer", True)
+                dokumentList.Fill()
+                For Each dokumentId As String In dokumentList.DokumentIds
+                    Dim edokaDokument As EdokaDokument = New EdokaDokument()
+                    edokaDokument.Id = dokumentId
+                    Me.Items.Add(edokaDokument)
+                Next
+                If Me.Items.Count = 0 Then
+                    Dim lsvIds As String = XmlHelper.GetItemValueByTagName(Me.Contract, "lsvId")
+                    Dim numberOfLists As Integer = lsvIds.Split(";").Length
+                    If numberOfLists = 0 Then numberOfLists = 1
+
+                    For counter As Integer = 0 To numberOfLists - 1
+                        dokumentList = New DokumentList(Me.Contract, partnerNummer)
+                        dokumentList.AddSelektor("iban", "IBAN")
+                        dokumentList.AddSelektor("lsvId", "LSV-ID", False, counter)
+                        dokumentList.AddSelektor("openDate", "BE_LSV-ID_gueltig_ab", False, -1, True)
+                        dokumentList.AddSelektor("ref1", "Referenz1")
+                        dokumentList.AddSelektor("ref2", "Referenz2")
+                        dokumentList.Fill()
+                        For Each dokumentId As String In dokumentList.DokumentIds
+                            Dim edokaDokument As EdokaDokument = New EdokaDokument()
+                            edokaDokument.Id = dokumentId
+                            Me.Items.Add(edokaDokument)
+                        Next
+                    Next
+                End If
+            End If
+            Return ret
+        End Function
+    End Class
+End Namespace
+